Proyek Remot Arduino

Ditulis olehElectricdermayonDiposkan padaArduino, Arduino indonesia, Elektronik, Indonesia, Indramayu, MicrocontrollerTag:

Proyek Remott dengan Inframerah(IR)

Dikirim oleh Electric Dermayon

Komunikasi inframerah (IR) adalah teknologi nirkabel yang banyak digunakan dan mudah diimplementasikan yang memiliki banyak aplikasi yang berguna. Contoh paling menonjol dalam kehidupan sehari-hari adalah remote control TV/video, sensor gerak, dan termometer inframerah.

Ada banyak proyek Arduino menarik yang menggunakan komunikasi IR juga. Dengan pemancar dan penerima IR sederhana, Anda dapat membuat robot yang dikendalikan dari jarak jauh, sensor jarak, monitor detak jantung, kendali jarak jauh kamera DSLR, kendali jarak jauh TV, dan banyak lagi.

Dalam tutorial ini pertama saya akan menjelaskan apa itu inframerah dan bagaimana cara kerjanya. Kemudian saya akan menunjukkan cara mengatur penerima IR dan remote pada Arduino . Saya juga akan menunjukkan cara menggunakan hampir semua remote IR (seperti yang untuk TV Anda) untuk mengontrol hal-hal yang terhubung ke Arduino.

APA ITU INFRAMERAH?

Radiasi inframerah adalah bentuk cahaya yang mirip dengan cahaya yang kita lihat di sekitar kita. Satu-satunya perbedaan antara cahaya IR dan cahaya tampak adalah frekuensi dan panjang gelombang. Radiasi inframerah terletak di luar jangkauan cahaya tampak, sehingga manusia tidak dapat melihatnya:

Tutorial Arduino IR – Diagram Spektrum Elektromagnetik
Karena IR adalah jenis cahaya, komunikasi IR membutuhkan garis pandang langsung dari penerima ke pemancar. Itu tidak dapat mentransmisikan melalui dinding atau bahan lain seperti WiFi atau Bluetooth.

CARA KERJA REMOTE DAN PENERIMA IR

Sistem komunikasi inframerah yang khas memerlukan pemancar IR dan penerima IR. Pemancar terlihat seperti LED standar, kecuali ia menghasilkan cahaya dalam spektrum IR, bukan spektrum yang terlihat. Jika Anda melihat bagian depan remote TV, Anda akan melihat LED pemancar IR:

Tutorial Jarak Jauh Arduino IR – Mengirimkan LED pada Jarak Jauh
Jenis LED yang sama digunakan pada papan breakout pemancar IR untuk Arduino. Anda dapat melihatnya di bagian depan pemancar IR Keyes ini:

Tutorial Jarak Jauh Arduino IR – LED Pemancar IR 2
Penerima IR adalah fotodioda dan pra-penguat yang mengubah cahaya IR menjadi sinyal listrik. Dioda penerima IR biasanya terlihat seperti ini:

Tutorial Jarak Jauh Arduino IR – Dua Dioda Penerima IR
Beberapa mungkin muncul di papan breakout seperti ini:

MODULASI SINYAL IR

Cahaya IR dipancarkan oleh matahari, bola lampu, dan apa pun yang menghasilkan panas. Itu berarti ada banyak kebisingan cahaya IR di sekitar kita. Untuk mencegah noise ini mengganggu sinyal IR, digunakan teknik modulasi sinyal.

Dalam modulasi sinyal IR, encoder pada remote IR mengubah sinyal biner menjadi sinyal listrik termodulasi. Sinyal listrik ini dikirim ke LED transmisi. Transmisi LED mengubah sinyal listrik termodulasi menjadi sinyal cahaya IR termodulasi. Penerima IR kemudian mendemodulasi sinyal cahaya IR dan mengubahnya kembali menjadi biner sebelum meneruskan informasi ke mikrokontroler:

Tutorial Penerima Jarak Jauh Arduino IR – Modulasi Sinyal IR
Sinyal IR termodulasi adalah serangkaian pulsa cahaya IR yang dinyalakan dan dimatikan pada frekuensi tinggi yang dikenal sebagai frekuensi pembawa. Frekuensi pembawa yang digunakan oleh sebagian besar pemancar adalah 38 kHz, karena sifatnya yang langka sehingga dapat dibedakan dari kebisingan sekitar. Dengan cara ini penerima IR akan mengetahui bahwa sinyal 38 kHz dikirim dari pemancar dan tidak diambil dari lingkungan sekitar.

Dioda penerima mendeteksi semua frekuensi cahaya IR, tetapi memiliki filter band-pass dan hanya memungkinkan melalui IR pada 38 kHz. Kemudian memperkuat sinyal termodulasi dengan pre-amplifier dan mengubahnya menjadi sinyal biner sebelum mengirimkannya ke mikrokontroler.

PROTOKOL TRANSMISI IR

Pola di mana sinyal IR termodulasi diubah menjadi biner ditentukan oleh protokol transmisi. Ada banyak protokol transmisi IR. Sony, Matsushita, NEC, dan RC5 adalah beberapa protokol yang lebih umum.

Semua Iklan PCB
Protokol NEC juga merupakan jenis yang paling umum dalam proyek Arduino, jadi saya akan menggunakannya sebagai contoh untuk menunjukkan kepada Anda bagaimana penerima mengubah sinyal IR termodulasi menjadi biner.

Logika ‘1’ dimulai dengan pulsa HIGH panjang 562,5 s dari 38 kHz IR diikuti oleh pulsa LOW panjang 1,687,5 s. Logika ‘0’ ditransmisikan dengan pulsa HIGH panjang 562,5 s diikuti oleh pulsa LOW 562,5 s:

Tutorial Penerima Jarak Jauh Arduino IR – Protokol NEC
Ini adalah bagaimana protokol NEC mengkodekan dan mendekode data biner menjadi sinyal termodulasi. Protokol lain hanya berbeda dalam durasi pulsa TINGGI dan RENDAH individu.

KODE IR

Setiap kali Anda menekan tombol pada remote control, kode heksadesimal unik dihasilkan. Ini adalah informasi yang dimodulasi dan dikirim melalui IR ke penerima. Untuk menguraikan tombol mana yang ditekan, mikrokontroler penerima perlu mengetahui kode mana yang sesuai dengan setiap tombol pada remote.

Remote yang berbeda mengirimkan kode yang berbeda untuk penekanan tombol, jadi Anda harus menentukan kode yang dihasilkan untuk setiap tombol pada remote khusus Anda. Jika Anda dapat menemukan lembar data, kode kunci IR harus dicantumkan. Jika tidak, ada sketsa Arduino sederhana yang akan membaca sebagian besar kendali jarak jauh populer dan mencetak kode heksadesimal ke monitor serial saat Anda menekan tombol. Saya akan menunjukkan cara mengaturnya sebentar lagi, tetapi pertama-tama kita harus menghubungkan receiver ke Arduino…

CARA MENGHUBUNGKAN PENERIMA IR KE ARDUINO

Ada beberapa jenis penerima IR yang berbeda, ada yang berdiri sendiri, dan ada yang dipasang di papan breakout. Periksa lembar data untuk penerima IR khusus Anda karena pin mungkin disusun secara berbeda dari penerima IR HX1838 dan perangkat jarak jauh yang saya gunakan di sini. Namun, semua penerima IR akan memiliki tiga pin: sinyal, ground, dan Vcc.

Mari kita mulai dengan koneksi perangkat keras. Tata letak pin pada sebagian besar papan breakout terlihat seperti ini:

Pinout dari kebanyakan dioda yang berdiri sendiri adalah seperti ini:

Diagram Pinout Stand-Alone Penerima IR
Untuk menghubungkan penerima IR yang dipasang di papan breakout, sambungkan ke Arduino seperti ini:

Arduino IR Remote Receiver – Diagram Pengkabelan Papan Breakout
Untuk menghubungkan dioda penerima yang berdiri sendiri, sambungkan seperti ini:


Arduino IR Remote Receiver – Diagram Pengkabelan Penerima IR yang Berdiri Sendiri

MEMPROGRAM PENERIMA IR

Setelah penerima terhubung, kita dapat menginstal perpustakaan Arduino dan memulai pemrograman. Pada contoh di bawah ini, saya akan menunjukkan cara menemukan kode yang dikirim oleh remote Anda, cara menemukan protokol IR yang digunakan oleh remote Anda, cara mencetak penekanan tombol ke monitor serial atau LCD, dan terakhir, cara mengontrol pin output Arduino dengan remote.

INSTAL PERPUSTAKAAN IRREMOTE

Kami akan menggunakan perpustakaan IRremote untuk semua contoh kode di bawah ini. Anda juga dapat mengunduh file ZIP perpustakaan di Internet atau di situs http://www.arduino.cc.

Untuk menginstal library dari file ZIP, buka Arduino IDE, lalu buka Sketch > Include Library > Add .ZIP Library, lalu pilih file IRremote ZIP yang Anda download.

TEMUKAN KODE UNTUK REMOTE ANDA

Untuk menemukan kode kunci untuk remote control Anda, unggah kode ini ke Arduino Anda dan buka monitor serial:

#include <IRremote.h>

const int RECV_PIN = 7;
IRrecv irrecv(RECV_PIN);
decode_results results;

void setup(){
  Serial.begin(9600);
  irrecv.enableIRIn();
  irrecv.blink13(true);
}

void loop(){
  if (irrecv.decode(&results)){
        Serial.println(results.value, HEX);
        irrecv.resume();
  }

Sekarang tekan setiap tombol pada remote Anda dan catat kode heksadesimal yang dicetak untuk setiap penekanan tombol.

Dengan menggunakan program di atas, saya mendapatkan tabel kunci dan kode yang sesuai dari remote yang disertakan dengan receiver IR HX1838 dan remote set saya . Perhatikan bahwa Anda akan menerima kode 0XFFFFFFFF ketika Anda menekan tombol terus menerus.

Kunci       Kode
 CH-        0xFFA25D
 CH         0xFF629D
 CH+        0xFFE21D
 <<         0xFF22DD
 >>         0xFF02FD
 >>|        0xFFC23D
 -          0xFFE01F
 +          0xFFA857
 persamaan  0xFF906F
 100+       0xFF9867
 200+       0xFFB04F
 0           0XFF6897
 1           0xFF30CF
 2           0xFF18E7
 3           0xFF7A85
 4           0xFF10EF
 5           0xFF38C7
 6           0xFF5AA5
 7           0xFF42BD
 8           0xFF4AB5
 9           0xFF52AD

TEMUKAN PROTOKOL YANG DIGUNAKAN OLEH REMOTE ANDA

Mengetahui protokol mana yang digunakan jarak jauh Anda dapat berguna jika Anda ingin mengerjakan beberapa proyek yang lebih maju. Atau mungkin Anda hanya penasaran. Program di bawah ini akan mengidentifikasi protokol yang digunakan oleh remote Anda. Itu bahkan harus bekerja pada sebagian besar remote control di sekitar rumah Anda.

#include <IRremote.h>

const int RECV_PIN = 7;
IRrecv irrecv(RECV_PIN);
decode_results results;

void setup(){
  Serial.begin(9600);
  irrecv.enableIRIn();
  irrecv.blink13(true);
}

void loop(){
  if (irrecv.decode(&results)){
        Serial.println(results.value, HEX);
        switch (results.decode_type){
            case NEC: Serial.println("NEC"); break ;
            case SONY: Serial.println("SONY"); break ;
            case RC5: Serial.println("RC5"); break ;
            case RC6: Serial.println("RC6"); break ;
            case DISH: Serial.println("DISH"); break ;
            case SHARP: Serial.println("SHARP"); break ;
            case JVC: Serial.println("JVC"); break ;
            case SANYO: Serial.println("SANYO"); break ;
            case MITSUBISHI: Serial.println("MITSUBISHI"); break ;
            case SAMSUNG: Serial.println("SAMSUNG"); break ;
            case LG: Serial.println("LG"); break ;
            case WHYNTER: Serial.println("WHYNTER"); break ;
            case AIWA_RC_T501: Serial.println("AIWA_RC_T501"); break ;
            case PANASONIC: Serial.println("PANASONIC"); break ;
            case DENON: Serial.println("DENON"); break ;
          default:
            case UNKNOWN: Serial.println("UNKNOWN"); break ;
          }
        irrecv.resume();
 }
}

CETAK KUNCI KE SERIAL MONITOR

Saya memperluas kode di atas untuk mencetak nilai kunci alih-alih kode heksadesimal:

#include <IRremote.h>

const int RECV_PIN = 7;
IRrecv irrecv(RECV_PIN);
decode_results results;
unsigned long key_value = 0;

void setup(){
  Serial.begin(9600);
  irrecv.enableIRIn();
  irrecv.blink13(true);
}

void loop(){
  if (irrecv.decode(&results)){
 
        if (results.value == 0XFFFFFFFF)
          results.value = key_value;

        switch(results.value){
          case 0xFFA25D:
          Serial.println("CH-");
          break;
          case 0xFF629D:
          Serial.println("CH");
          break;
          case 0xFFE21D:
          Serial.println("CH+");
          break;
          case 0xFF22DD:
          Serial.println("|<<");
          break;
          case 0xFF02FD:
          Serial.println(">>|");
          break ;  
          case 0xFFC23D:
          Serial.println(">|");
          break ;               
          case 0xFFE01F:
          Serial.println("-");
          break ;  
          case 0xFFA857:
          Serial.println("+");
          break ;  
          case 0xFF906F:
          Serial.println("EQ");
          break ;  
          case 0xFF6897:
          Serial.println("0");
          break ;  
          case 0xFF9867:
          Serial.println("100+");
          break ;
          case 0xFFB04F:
          Serial.println("200+");
          break ;
          case 0xFF30CF:
          Serial.println("1");
          break ;
          case 0xFF18E7:
          Serial.println("2");
          break ;
          case 0xFF7A85:
          Serial.println("3");
          break ;
          case 0xFF10EF:
          Serial.println("4");
          break ;
          case 0xFF38C7:
          Serial.println("5");
          break ;
          case 0xFF5AA5:
          Serial.println("6");
          break ;
          case 0xFF42BD:
          Serial.println("7");
          break ;
          case 0xFF4AB5:
          Serial.println("8");
          break ;
          case 0xFF52AD:
          Serial.println("9");
          break ;      
        }
        key_value = results.value;
        irrecv.resume(); 
  }
}

Jika remote Anda mengirimkan kode yang berbeda dari yang ada di tabel di atas, ganti saja kode hex di setiap baris yang bertuliskan:

case 0xFFA25D:
Serial.println(“CH-“);
Pada baris ini, ketika kode hex 0xFFA25D diterima, Arduino mencetak “CH-“.

CARA KERJA KODE

Untuk komunikasi IR apa pun yang menggunakan perpustakaan IRremote, pertama-tama kita perlu membuat objek yang disebut irrecv dan menentukan nomor pin tempat penerima IR terhubung (baris 3). Objek ini akan menangani protokol dan pemrosesan informasi dari penerima.

Langkah selanjutnya adalah membuat objek bernama results, dari decode_resultskelas, yang akan digunakan oleh irrecvobjek untuk berbagi informasi yang didekodekan dengan aplikasi kita (baris 5).

Di void setup()blok, pertama kita konfigurasikan baud rate monitor serial. Selanjutnya kita memulai penerima IR dengan memanggil IRrecv fungsi anggota enableIRIn()(baris 10).

Fungsi pada baris 11 akan berkedip Arduino di papan LED setiap kali penerima mendapat sinyal dari remote control, yang berguna untuk debugging. irrecv.blink13(true)

Di void loop()blok, fungsi irrecv.decode akan mengembalikan true jika kode diterima dan program akan mengeksekusi kode dalam pernyataan if. Kode yang diterima disimpan dalam results.value. Kemudian saya menggunakan sakelar untuk menangani setiap kode IR dan mencetak nilai kunci yang sesuai.

Sebelum blok sakelar dimulai, ada blok bersyarat:

if (results.value == 0XFFFFFFFF)
results.value = key_value;
Jika kita menerima 0XFFFFFFFF dari remote, itu berarti pengulangan dari kunci sebelumnya. Jadi untuk menangani pola kunci berulang, saya menyimpan kode hex dalam variabel global key_valuesetiap kali kode diterima:

key_value = results.value;

Saat Anda menerima pola pengulangan, maka nilai yang disimpan sebelumnya digunakan sebagai penekanan tombol saat ini.

Di akhir void loop() bagian, kami memanggil irrecv.resume() untuk mengatur ulang penerima dan mempersiapkannya untuk menerima kode berikutnya.

CETAK KUNCI KE LCD

Alih-alih mencetak nilai kunci ke monitor serial, Anda juga dapat menampilkan informasi pada LCD. Lihat artikel kami tentang pengaturan dan pemrograman LCD pada Arduino untuk informasi lebih lanjut tentang pemrograman LCD, tetapi pengaturan dasarnya terlihat seperti ini:



Arduino IR Remote – Cetak Kunci ke LCD
Resistor mengatur kecerahan lampu latar LCD. Itu bisa apa saja dari 200 ohm hingga sekitar 2K ohm. Potensiometer mengatur kontras karakter. Saya biasanya menggunakan potensiometer 10K ohm untuk yang satu ini.

Setelah semuanya terhubung, unggah kode ini ke Arduino:

#include <IRremote.h>
#include <LiquidCrystal.h>

const int RECV_PIN = 7;
LiquidCrystal lcd(12, 11, 5, 4, 3, 2);
IRrecv irrecv(RECV_PIN);
decode_results results;
unsigned long key_value = 0;

void setup(){
  Serial.begin(9600);
  irrecv.enableIRIn(); 
  irrecv.blink13(true);
  lcd.begin(16, 2);
}

void loop(){
  if (irrecv.decode(&results)){
 
        if (results.value == 0XFFFFFFFF)
        results.value = key_value;
        lcd.setCursor(0, 0);
        lcd.clear();
        
        switch(results.value){
          case 0xFFA25D:          
          lcd.print("CH-");
          break;
          case 0xFF629D:
          lcd.print("CH");
          break;
          case 0xFFE21D:
          lcd.print("CH+");
          break;
          case 0xFF22DD:
          lcd.print("|<<");
          break;
          case 0xFF02FD:
          lcd.print(">>|");
          break ;  
          case 0xFFC23D:
          lcd.print(">|");
          break ;               
          case 0xFFE01F:
          lcd.print("-");
          break ;  
          case 0xFFA857:
          lcd.print("+");
          break ;  
          case 0xFF906F:
          lcd.print("EQ");
          break ;  
          case 0xFF6897:
          lcd.print("0");
          break ;  
          case 0xFF9867:
          lcd.print("100+");
          break ;
          case 0xFFB04F:
          lcd.print("200+");
          break ;
          case 0xFF30CF:
          lcd.print("1");
          break ;
          case 0xFF18E7:
          lcd.print("2");
          break ;
          case 0xFF7A85:
          lcd.print("3");
          break ;
          case 0xFF10EF:
          lcd.print("4");
          break ;
          case 0xFF38C7:
          lcd.print("5");
          break ;
          case 0xFF5AA5:
          lcd.print("6");
          break ;
          case 0xFF42BD:
          lcd.print("7");
          break ;
          case 0xFF4AB5:
          lcd.print("8");
          break ;
          case 0xFF52AD:
          lcd.print("9");
          break ;                   
        }
        key_value = results.value;
        irrecv.resume(); 
  }
}

Sekali lagi, jika kode hex tidak cocok dengan kode yang dikeluarkan oleh remote Anda, ganti saja untuk setiap karakter yang tertulis case 0xXXXXXXXX;.

MENGGUNAKAN REMOTE IR UNTUK MENGONTROL BERBAGAI HAL

Sekarang saya akan menunjukkan kepada Anda demonstrasi sederhana tentang bagaimana Anda dapat menggunakan remote IR untuk mengontrol pin output Arduino. Dalam contoh ini, kita akan menyalakan LED ketika tombol tertentu ditekan. Anda dapat dengan mudah memodifikasi kode untuk melakukan hal-hal seperti mengontrol motor servo, atau mengaktifkan relai dengan menekan tombol apa pun dari remote.

Contoh rangkaian memiliki penerima IR yang terhubung ke Arduino, dengan LED merah terhubung ke pin 10 dan LED hijau terhubung ke pin 11:


Arduino IR Remote Receiver – Mengontrol LED dengan IR Remote
Kode di bawah ini akan menulis pin digital 10 HIGH selama 2 detik saat tombol “5” ditekan, dan menulis pin digital 11 HIGH selama 2 detik saat tombol “2” ditekan:

#include <IRremote.h>

const int RECV_PIN = 7;
IRrecv irrecv(RECV_PIN);
decode_results results;
const int redPin = 10;
const int greenPin = 11;


void setup(){
  irrecv.enableIRIn();
  irrecv.blink13(true);
  pinMode(redPin, OUTPUT);
  pinMode(greenPin, OUTPUT);
}

void loop(){
    if (irrecv.decode(&results)){

        switch(results.value){
          case 0xFF38C7: //Keypad button "5"
          digitalWrite(redPin, HIGH);
          delay(2000);
          digitalWrite(redPin, LOW);
          }

        switch(results.value){
          case 0xFF18E7: //Keypad button "2"
          digitalWrite(greenPin, HIGH);
          delay(2000);
          digitalWrite(greenPin, LOW);
          }

        irrecv.resume(); 
    }
}

Sejauh ini kita telah membahas sifat-sifat radiasi infra merah dan bagaimana komunikasi terjadi antara pemancar dan penerima. Kami melihat bagaimana mengidentifikasi kode kunci IR untuk remote control yang diberikan. Kami belajar bagaimana menampilkan penekanan tombol pada monitor serial dan pada layar LCD.

Akhirnya saya menunjukkan cara mengontrol output Arduino dengan remote. Bersenang-senang bermain dengan ini dan pastikan untuk memberi tahu kami di komentar jika Anda memiliki pertanyaan atau kesulitan mengaturnya!

Terima Kasih banyak atas Kunjungan Anda

Di Publikasikan oleh Electric Dermayon©

Lihat Postingan lainnya

Tinggalkan komentar

Rancang situs seperti ini dengan WordPress.com
Mulai